コツコツエンジニアノート

Unityドット欠けシェーダー

[Unity uGUI] ドット欠けシェーダー。ピクセルが虫食いで欠けていく演出。
(Dead Pixel Shader)

#UnityShader

投稿日:2024-05-11

更新日:2025-07-10

ドット欠けシェーダー、コード全文

下がドット欠けシェーダーのサンプル動画です。

以下がコード全文です。uGUI Imageへの反映方法はこちらの記事参照。

Shader "UI/DeadPixel"
{
    Properties
    {
        _VanishPow ("VanishPow", Range(0.0, 1.0)) = 0

//消滅する力、1で全てのドットが消える

_Roughness ("Roughness", Range(1, 100.0)) = 15

//欠けていくドットの粗さ

    }

    SubShader
    {
        Tags { "Queue" = "Transparent" }
        Cull Off
        ZWrite Off
        Blend SrcAlpha OneMinusSrcAlpha

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            struct appdata
            {
                fixed2 uv : TEXCOORD0;
                fixed4 vertex : POSITION;
                fixed4 color : COLOR;
            };

            struct v2f
            {
                fixed2 uv : TEXCOORD0;
                fixed4 vertex : POSITION;
                fixed4 color : COLOR;
            };

            sampler2D _MainTex;

//アタッチされたSpriteのサイズを取得(x=1.0/width, y=1.0/height, z=width, w=height)

            float4 _MainTex_TexelSize;

            float _VanishPow;
            float _Roughness;

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = v.uv;
                o.color = v.color;
                return o;
            }

//1次元疑似ランダム(入力は2次元です)

            float random(fixed2 st)
            {
                return frac(sin(dot(st.xy, fixed2(12.9898, 78.233))) * 43758.5453);
            }

            fixed4 frag (v2f i) : SV_Target
            {
                fixed4 col = tex2D(_MainTex, i.uv);

//アタッチされたSpriteの縦横比をratioに保存

fixed ratio = _MainTex_TexelSize.z / _MainTex_TexelSize.w;

//_Roughnessの入力値を実際に使う値まで細かくする

fixed fixRough = _Roughness * 0.001f;

//対象ピクセルのx座標とy座標を保存、ただしfixRoughの値に応じて座標の取得が大雑把になる

//またy座標にはratioを追加で掛けることで、座標を大雑把にした時の値に補正を乗せて欠けるドットを正方形に修正する

                fixed roughX = floor(i.uv.x / fixRough) * fixRough;
                fixed roughY = floor(i.uv.y / (fixRough * ratio)) * (fixRough * ratio);
                fixed2 roughUv = fixed2(roughX, roughY);

//ランダムノイズにより、指定座標に対し0~1のランダムな値が返ってくる

fixed rdm = random(roughUv);

//ランダムノイズから_VanishPowを引き、その値が0未満になった時対象ドットを消滅させる

                fixed doVanish = step(0, rdm - _VanishPow);

                col *= i.color;
                col.a = col.a * doVanish;

                return col;
            }
            ENDCG
        }
    }
}