Unity uGUI用、虹色シェーダー。画像をレインボーに光らせる実装。
(Rainbow Shader for Unity uGUI)

Shader "UI/Rainbow"
{
    Properties
    {
        _HueBlendRate("Hue Blend Rate", Range(0.1, 5)) = 2 
        _OverrideRate("Override Rate", Range(0, 1)) = 1 
        _HueOffset("Hue Offset", float) = 0 

        [Space]
        
        [KeywordEnum(ToShiny, ToDark)] _HUETYPE("HueType", Int) = 0
        
        [KeywordEnum(Circle, Vertical, Horizontal)] _GRADATIONTYPE("GradationType", Int) = 0
    }

    SubShader
    {
        Tags { "Queue" = "Transparent" }
        Cull Off
        ZWrite Off
        Blend SrcAlpha OneMinusSrcAlpha

        CGINCLUDE

        #pragma vertex vert
        #pragma fragment frag

        struct appdata
        {
            float4 vertex : POSITION;
            float4 color : COLOR;
            float2 uv : TEXCOORD0;
        };

        struct v2f
        {
            float4 vertex : POSITION;
            fixed4 color : COLOR;
            float2 uv : TEXCOORD0;
        };

        sampler2D _MainTex;

        fixed _HueBlendRate;
        fixed _OverrideRate;
        fixed _HueOffset;

        #pragma multi_compile _HUETYPE_TOSHINY _HUETYPE_TODARK
        #pragma multi_compile _GRADATIONTYPE_CIRCLE _GRADATIONTYPE_VERTICAL _GRADATIONTYPE_HORIZONTAL

        v2f vert(appdata v)
        {
            v2f o;
            o.vertex = UnityObjectToClipPos(v.vertex);
            o.uv = v.uv;
            o.color = v.color;
            return o;
        }

        ENDCG

        
        Pass
        {
            CGPROGRAM

            fixed4 frag (v2f i) : SV_Target
            {
                fixed4 col = tex2D(_MainTex, i.uv);
                col *= i.color;
                return col;
            }

            ENDCG
        }

        
        Pass
        {
            CGPROGRAM
 
            fixed3 HUEtoRGB(in float H)
            {
                float R = abs(H * 6 - 3) - 1;
                float G = 2 - abs(H * 6 - 2);
                float B = 2 - abs(H * 6 - 4);
                return saturate(float3(R, G, B));
            }

            fixed4 frag(v2f IN) : SV_Target
            {
                fixed4 color = (tex2D(_MainTex, IN.uv)) * IN.color;
                fixed hueOffset = max(0, _HueOffset);
                fixed3 hueColor;

#ifdef _GRADATIONTYPE_CIRCLE
                
                float pi2 = 6.283184;
                float rad = (atan2(IN.uv.y - 0.5, IN.uv.x - 0.5) + (hueOffset / 2 * pi2) + pi2) % pi2 / pi2;
                hueColor= (HUEtoRGB(rad) / _HueBlendRate);
#elif _GRADATIONTYPE_VERTICAL
                
                hueColor= (HUEtoRGB((IN.uv.y + hueOffset) % 1) / _HueBlendRate);
#elif _GRADATIONTYPE_HORIZONTAL
                
                hueColor= (HUEtoRGB((IN.uv.x + hueOffset) % 1) / _HueBlendRate);
#endif

#ifdef _HUETYPE_TOSHINY
                
                color.xyz *= 1 / hueColor;
#elif _HUETYPE_TODARK
                
                color.xyz *= hueColor;
#endif

                
                color.a *= _OverrideRate;
                return color;
            }

            ENDCG
        }
    }
}