Unity uGUI用、松明シェーダー。昔のRPGの洞窟内のような表現。
(Torch Shader for Unity uGUI)

Shader "UI/Torch"
{
    Properties
    {
        [HideInInspector]_MainTex("-",2D)="white"{} 
        _OverlapColor("OverlapsColor", Color) = (0.35,0.5,1,1)

        [Space(10)]
        _TorchRange("TorchRange", Range(0, 1)) = 0.4
        _FadeRange("FadeRange", Range(0.001, 1)) = 0.3
        _DarknessColor("DarknessColor", Color) = (0,0,0,1)

        [Space(10)]
        _GlowRange("GlowRange", Range(0.001, 1)) = 1
        _GlowPower("GlowPow", Range(0, 1)) = 0.8
        _GlowColor("GlowColor", Color) = (1,0.55,0.3,1)
    }

    SubShader
    {
        Tags { "Queue" = "Transparent" }
        Cull Off
        ZWrite Off
        Blend SrcAlpha OneMinusSrcAlpha

        GrabPass{}

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"

            struct appdata
            {
                fixed2 uv : TEXCOORD0;
                fixed4 vertex : POSITION;
                fixed4 color : COLOR;
            };

            struct v2f
            {
                fixed2 uv : TEXCOORD0;
                fixed4 vertex : POSITION;
                fixed4 color : COLOR;
            };
            
            sampler2D _GrabTexture;
            float4 _GrabTexture_TexelSize;

            fixed4 _OverlapColor;

            fixed _TorchRange;
            fixed _FadeRange;
            fixed4 _DarknessColor;

            fixed _GlowPower;
            fixed _GlowRange;
            fixed4 _GlowColor;

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = ComputeGrabScreenPos(o.vertex);
                o.color = v.color;
                return o;
            }

            fixed getDistance(v2f i)
            {
                fixed2 centerPos = fixed2(0.5, 0.5);

                
                fixed minScreen = min(_ScreenParams.x, _ScreenParams.y);
                
                fixed fixX = centerPos.x + (i.uv.x - centerPos.x) * (minScreen / _ScreenParams.y);
                fixed fixY = centerPos.y + (i.uv.y - centerPos.y) * (minScreen / _ScreenParams.x);
                
                fixed diffX = abs(fixX - centerPos.x);
                fixed diffY = abs(fixY - centerPos.y);

                
                return sqrt(pow(diffX, 2) + pow(diffY, 2)) * 2;
            }

            fixed4 getInTorchColor(fixed4 col, fixed distance)
            {
                
                fixed glowRate = 1 - (saturate(distance / (_TorchRange * _GlowRange)));
                
                fixed4 maxGlowColor = col * (1 + _GlowPower)* (1 + _GlowPower) * _GlowColor;

                
                
                return (1 - glowRate) * col + glowRate * maxGlowColor;
            }

            fixed4 getOutTorchColor(fixed4 col, fixed distance)
            {
                
                fixed fadeRate = 1 - (saturate(_FadeRange - (distance - _TorchRange)) / _FadeRange);

                
                
                return (1 - fadeRate) * col + fadeRate * _DarknessColor;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                fixed4 col = tex2D(_GrabTexture, i.uv);
                
                col *= _OverlapColor;

                
                fixed distance = getDistance(i);

                
                fixed4 inTorchColor = getInTorchColor(col, distance);
                
                fixed4 outTorchColor = getOutTorchColor(col, distance);

                
                fixed isInTorchRange = step(distance, _TorchRange);
                
                return isInTorchRange * inTorchColor + (1 - isInTorchRange) * outTorchColor;
            }
            ENDCG
        }
    }
}